///Ejercicio Modelo (2023)

///Enunciado
///Dada una matriz de orden n * m (donde n y m son valores ingresados por el usuario) realizar un
///programa que calcule y muestre la suma de los números pares y la suma de los números impares.
///Mostrar la matriz y los resultados por pantalla.

Algoritmo ejercicioModeloMatriz
	
	//Definimos la variables que el usuario utilizará para indicar la cantidad de filas y columnas
	//Definimos las variables donde se totalizaran la cantidad de números pares e impares
	//Definimos la matriz que se utilizará en el programa
	Definir filas, columnas, cantidadNumerosPares, cantidadNumerosImpares Como Entero
	Definir matriz Como Entero
	
	//Inicializamos los totalizadores
	cantidadNumerosPares=0
	cantidadNumerosImpares=0
	
	//Solicitamos al usuario que ingrese los valores n (filas) que tendrá la matriz	
	filas = leerCardinalidad("Indique la cantidad de filas (N).")
	
	//Solicitamos al usuario que ingrese los valores  m (columnas) que tendrá la matri
	columnas =  leerCardinalidad("Indique la cantidad de columnas (M).")
	
	Escribir " "
	
	//Creamos la matriz con las dimensiones definidas
	Dimension matriz(filas, columnas)
	
	//Inicializamos la matriz con todos sus valores en 0
	inicializarMatriz(matriz, filas, columnas)
	
	//Mostramos los valores de la matriz por pantalla
	mostrarMatriz(matriz, filas, columnas)
	
	Escribir " "
	Escribir "--------------------------------"
	Escribir " " 
	
	//Completamos nuestra matriz con números pares e impares de forma aleatoria de 1 a 50
	generarValores(matriz, filas, columnas)
	
	//Mostramos los valores de la matriz por pantalla
	mostrarMatriz(matriz, filas, columnas)
	
	//Determinamos la cantidad de valores pares e impares de la matriz
	obtenerTotalesParesEImpares(matriz, filas, columnas, cantidadNumerosPares, cantidadNumerosImpares)
	
	//Mostramos por pantalla las cantidades totales de número pares e impares
	Escribir " "
	Escribir "--------------------------------"
	Escribir " " 
	Escribir "Cantidad números pares: " cantidadNumerosPares
	Escribir "Cantidad números impares: " cantidadNumerosImpares
	
FinAlgoritmo

//SubProceso que se encarga de inicializar el listado de notas con todos
//su valores en 0
SubProceso inicializarMatriz(matriz Por Referencia, filas, columnas)
	
	//Definimos los itereadores del bucle Para
	//que recorrerá la matriz
	Definir i, j Como Entero
	
	//Recorremos la matriz y asignamos en todas sus posiciones el valor 0
	Para i = 0 Hasta filas-1 Con Paso 1 Hacer
		Para j = 0 Hasta columnas-1 Con Paso 1 Hacer
			matriz(i,j) = 0
		FinPara
	FinPara
	
FinSubProceso

//SubProceso que se encarga de mostrar los valores de 
//la matriz por pantalla. Recibe la cantidad de filas 
//y columnas para poder recorrerla
SubProceso mostrarMatriz(matriz Por Referencia, filas, columnas)
	
	//Definimos los itereadores del bucle Para
	//que recorrerá la matriz
	Definir i, j Como Entero
	
	//Recorremos la matriz y mostramos por pantalla el contenido de cada
	//una de sus posiciones.
	Para i = 0 Hasta filas-1 Con Paso 1 Hacer
		Para j = 0 Hasta columnas-1 Con Paso 1 Hacer
			Escribir "[" matriz(i,j) "]" Sin Saltar	
		FinPara
        Escribir " " 
	FinPara
	
FinSubProceso

//SubProceso que se encarga de asignar a cada posición de la matriz de forma aleatoria
//un valor par o impar
SubProceso generarValores(matriz Por Referencia, filas, columnas)
	
	//Definimos los itereadores del bucle Para
	//que recorrerá la matriz
	Definir i, j Como Entero
	
	//Recorremos la matriz y asignamos valores aleatorios entre 1 y 50
	Para i = 0 Hasta filas-1 Con Paso 1 Hacer
		Para j = 0 Hasta columnas-1 Con Paso 1 Hacer
			matriz(i,j) = Aleatorio(1,50)
		FinPara
	FinPara
	
FinSubProceso

//SubProceso que se encarga de determinar la cantidad de valores pares e impares
//existente en la matriz
SubProceso obtenerTotalesParesEImpares(matriz Por Referencia, filas, columnas, cantidadNumerosPares por Referencia, cantidadNumerosImpares Por Referencia)
	
	//Definimos los itereadores del bucle Para
	//que recorrerá la matriz
	Definir i, j Como Entero

	//Recorremos la matriz y asignamos valores aleatorios entre 1 y 50
	Para i = 0 Hasta filas-1 Con Paso 1 Hacer
		Para j = 0 Hasta columnas-1 Con Paso 1 Hacer
			
			//Se incrementa el tal dependiendo de si es par o impar
			Si esNumeroPar(matriz(i,j)) Entonces
				cantidadNumerosPares = cantidadNumerosPares + 1	
			SiNo
				cantidadNumerosImpares = cantidadNumerosImpares + 1
			FinSi
			
		FinPara
	FinPara
	
FinSubProceso

//Funcion para leer una cardinalidad de una dimension
Funcion tamanioDimension <- leerCardinalidad(mensaje)
	Definir tamanioDimension Como Entero
	Hacer
		Escribir mensaje
		leer tamanioDimension
	Mientras Que tamanioDimension < 1
FinFuncion

//Función que permite determinar si un número es par 
Funcion esPar <- esNumeroPar(num)
	
	//Definimos e inicializamos la variable que contendrá el valor lógico
	//si un número es par
	Definir esPar Como Logico
	esPar = (num % 2 = 0)

FinFuncion


////////////////////////////////////////////////////////////////////////////////////////////
///Propuesta para realizar en casa

///-Realizar un SubProceso donde coloque, en la matriz, el valor 1 donde los iteradores de filas (i) y columnas (j)
/// sean iguales. En las restantes posiciones coloque el valor 2. Luego Mostrar la matriz por pantalla.

///-Realizar un SubProceso que permita modificar una posición fila (i) columna (j). Luego ejecutar el programa con
/// una matriz de 3x3. Luego mostrar la matriz por pantalla

////////////////////////////////////////////////////////////////////////////////////////////